From news-rocq.inria.fr!jussieu.fr!fu-berlin.de!newsfeed.ecrc.net!cpk-news-hub1.bbnplanet.com!news.bbnplanet.com!rill.news.pipex.net!pipex!bore.news.pipex.net!pipex!not-for-mail Fri Apr 17 13:01:10 1998
Article: 8844 of rec.games.corewar
Path: news-rocq.inria.fr!jussieu.fr!fu-berlin.de!newsfeed.ecrc.net!cpk-news-hub1.bbnplanet.com!news.bbnplanet.com!rill.news.pipex.net!pipex!bore.news.pipex.net!pipex!not-for-mail
From: Robert Macrae <ff95@dial.pipex.com>
Newsgroups: rec.games.corewar
Subject: Seven-Eleven
Date: Thu, 16 Apr 1998 18:56:21 -0700
Organization: UUNet UK server (post doesn't reflect views of UUNet UK)
Lines: 84
Message-ID: <3536B6C5.3ADC@dial.pipex.com>
NNTP-Posting-Host: ac099.du.pipex.com
Mime-Version: 1.0
Content-Type: text/plain; charset=us-ascii
Content-Transfer-Encoding: 7bit
X-Mailer: Mozilla 2.0 (Win95; I; 16bit)

Seven-Eleven

Paul recommended that I try my entry from round 3, an anti-paper-optimised HSA
variant, against the hill. I did so with fair if transitory results; I entered
at #7, but was kicked off in under 10 challenges :-(

Very little has changed from the original. Most importantly, I moved from the
original SPL #1,{1 bombs to SPL #0,{0. This will avoid re-carpeting areas which
have already been bombed unless there are enemy processes present to trigger
the .f scan. It gains against papers, but against imps it may well be weaker as
I suspect re-carpeting helps. Less time spent re-carpeting permits a longer SPL
phase, hence greater certainty of stunning papers.

However, the downside is that a single SPL becomes hard to find at the DAT
clearing stage, giving rise to lots of draws, so I use DAT #0, {0 to clear.
This ensures that I will re-carpet any area that contained processes on the
first pass, and the second carpet is likely to cover any SPLs missed the first
time.

After lots of failed tweaks, I eventually settled on slightly smaller step
sizes than the original. In part this helps by pulling in the pointer and
reducing vulnerability to Silk strip-bombs; in part (I think) it interacts with
the spacing of the papers. The reduction in step-size was particularly
effective against Timescape for some reason.



;redcode-94
;name Seven-Eleven
;author Robert Macrae
;assert CORESIZE == 8000
;strategy Familiar-looking 80% f-scanner with
;strategy tweaked bombs and step sizes.

; 1.0   Switches to SPL #0,{0. This gives away far too many draws;
;       so change clear to DAT #0,{0.
; 1.1   Tries a run of 17 self scans, with minor pickup vs papers.
; 1.1g  tries NO decoy; strangely this seems better than an tuned
;       anti-QS one? I expected a decoy at -100 to be very effective.
; 1.1gi Finally try different steps.


tPtr      dat    100      ,4100-4        ; widely-spaced pointers

          dat    0,0
          dat    0,0
          dat    0,0
          
tWipe     mov    tSpl     ,<tPtr         ; positive wipe of opponent from x-2
          mov    >tPtr    ,>tPtr
          jmn.f  tWipe    ,>tPtr         ; first check at x
          
tScan     sub.x  #-11     ,tPtr          ; increment and look
          sne.f  *tPtr    ,@tPtr
          sub.x  *pScan   ,@tScan        ; increment and look
          jmn.f  tSelf    ,@tPtr
          jmz.f  tScan    ,*tPtr
pScan     mov.x  @tScan   ,@tScan        ; swap pointers for attack
tSelf     slt.b  @tScan   ,#tEnd+4-tPtr  ; self-check
          djn    tWipe    ,@tScan        ;   go to attack x-1
          djn    *pScan   ,#17           ; after 13 self-scans
          jmp    *pScan   ,}tWipe        ;   switch to dat-wiping

          dat    0,0

tSpl      spl    #0,{0
          dat    0,{0
          
          dat    0,0
tEnd      dat    0,0
      
      for 70
          dat    0,0
      rof
         
          end    tScan+1


-- 

Regards,

Robert Macrae